kickdot/tests/test_sqlite_install.gd at master · graphnode/kickdot · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
## Live test of the godot-sqlite installer: downloads the release zip and extracts
## the addon into a scratch root (not the real project). Needs network. Run headless:
##   godot --headless -s tests/test_sqlite_install.gd
extends SceneTree

const SKSqliteInstaller := preload("res://addons/kickdot/editor/sk_sqlite_installer.gd")

const SCRATCH_ROOT := "user://test_sqlite_install"
const TIMEOUT_MSEC := 300 * 1000

var _installer: SKSqliteInstaller
var _started_msec := 0
var _failures := 0


func _init() -> void:
	_started_msec = Time.get_ticks_msec()
	process_frame.connect(_on_frame)
	_installer = SKSqliteInstaller.new()
	_installer.install_root = SCRATCH_ROOT
	root.add_child(_installer)
	_installer.finished.connect(_on_finished)
	_installer.start()


func _on_frame() -> void:
	if Time.get_ticks_msec() - _started_msec > TIMEOUT_MSEC:
		print("FAIL: timed out")
		quit(1)


func _on_finished(error: String) -> void:
	_check(error.is_empty(), "install finished without error (got '%s')" % error)
	var base := SCRATCH_ROOT.path_join("addons/godot-sqlite")
	_check(FileAccess.file_exists(base.path_join("gdsqlite.gdextension")), "gdextension file present")
	var windows_dll := base.path_join("bin/libgdsqlite.windows.template_debug.x86_64.dll")
	_check(FileAccess.file_exists(windows_dll), "windows debug binary present")
	var size := 0
	var file := FileAccess.open(windows_dll, FileAccess.READ)
	if file != null:
		size = file.get_length()
	_check(size > 1024 * 1024, "windows binary plausibly sized (%d bytes)" % size)
	print("PASS" if _failures == 0 else "FAIL: %d checks failed" % _failures)
	quit(0 if _failures == 0 else 1)


func _check(ok: bool, what: String) -> void:
	if not ok:
		_failures += 1
	print("  %s %s" % ["ok " if ok else "FAIL", what])